WSUS Icon für nicht Admins

@echo off
:: Dieses Script schaltet das WSUS Icon für User auf dem PC an und auch wieder aus
:: PSEXEC.exe wird benötigt
color 70
cls
echo Dieses Script muss mit Adminrechten der Zielmaschine gestartet werden!
echo ======================================================================
echo.
:loop
echo --------------------------------------
set /p pc=Bitte PC Name eingeben:
echo --------------------------------------
echo.
echo Stoppe WSUS ...
start /wait psexec.exe \\%pc% -accepteula net stop wuauserv
echo Aktiviere WSUS Icon ...
start /wait psexec.exe \\%pc% -accepteula reg add HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /v ElevateNonAdmins /t REG_DWORD /d "00000001" /f
echo Starte WSUS ...
start /wait psexec.exe \\%pc% -accepteula net start wuauserv
:: Evtl. die 2 nachfolgenden Zeilen auskommentieren
echo 60 sec. warten ...
ping 127.0.0.1 -n 60>nul
::
echo.
echo Nun sollte der User das Icon sehen.
echo.
:: Jetzt kann auf der Zielmaschine das Patchen angestossen werden
pause
echo.
echo Stoppe WSUS ...
start /wait psexec.exe \\%pc% -accepteula net stop wuauserv
echo Deaktiviere WSUS Icon ...
start /wait psexec.exe \\%pc% -accepteula reg add HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate /v ElevateNonAdmins /t REG_DWORD /d "00000000" /f
echo Starte WSUS ...
start /wait psexec.exe \\%pc% -accepteula net start wuauserv
echo.
echo Nun sollte der User das Icon nicht mehr sehen.
echo.
echo - Fertig -
echo.
echo --------------------------------------
set /p temp=Noch ein PC? (j/n)
if "%temp%"=="j" goto loop
echo.
echo - Ende -
echo.
pause
exit